(бухай): программируй

Неделю не занимался игрой, но время пришло...
Я все пытаюсь отгородить себя как-то от написания ролевой системы, потому что до сих пор не понимаю, что с ней делать.
Поэтому я решил оптимизировать уже написанный код. И первыми в очереди оказались функции выбора оружия.
До этого я действовал максимально тупо: проверял, какая из кнопок клавиатуры (от 1 до 8) нажата, и под каждую кнопку была отдельная функция:

; ++++++++++ CHECK FOR WEAPON CHANGES KEY PRESSES ++++++++++
check_change_weapons_keys
        lda     key_pressed
        bne     @check_wrench
        jmp     @end
; проверка кнопки "1"
@check_wrench
        cmp     #49
        bne     @check_pistol
        ; если ключ доступен
        lda     weapons_avaliable
        beq     @check_pistol
        
        lda     curr_weapon_number
        beq     @check_pistol ; если оружие != ключ
        ldy     #$ce ; убрать текущее оружие
        jsr     choose_weapon_draw
        lda     #0
        sta     curr_weapon_number
        jsr     select_weapon_data ; выбрать ключ
        ldy     #$cd
        jsr     choose_weapon_draw ; нарисовать селектор ключа
        jmp     @end
@check_pistol
        cmp     #50
        bne     @check_nailer
        ; если пистолет доступен
        lda     weapons_avaliable+1
        beq     @check_nailer
        lda     curr_weapon_number
        cmp     #1
        beq     @check_nailer ; если оружие != пистолет
        ldy     #$ce
        jsr     choose_weapon_draw
        lda     #1
        sta     curr_weapon_number
        jsr     select_weapon_data
        ldy     #$cd
        jsr     choose_weapon_draw
        jmp     @end

И так далее, и так далее. И это действительно было очень тупо.
Но сейчас я немного оптимизировал код:

check_change_weapons_keys_new
        lda     key_pressed
        sec
        sbc     #49 ; кнопка "1" = 49 в десятичной
        ; если ни одна из кнопок "1" - "7" не нажата
        cmp     #7
        bcs     @end
        tax
        stx     $05 ; временная переменная для регистра X
        lda     weapons_avaliable,x ; если оружие доступно
        beq     @end
        lda     curr_weapon_number ; если новое оружие != текущее оружие
        cmp     $05
        beq     @end
        ldy     #$ce ; убрать текущее оружие
        jsr     choose_weapon_draw
        ldx     $05
        stx     curr_weapon_number ; переместить данные нового оружия в память
        jsr     select_weapon_data
        ldy     #$cd ; нарисовать селектор нового оружия
        ldx     $05
        jsr     choose_weapon_draw
@end
        rts

И это вся функция.

Дело в том, что кнопки от 1 до 8 имеют кодировку от 49 до 57. И остается только вычесть из нажатой кнопки 49. Получится цифра от 0 до 7.
Потом надо проверить, выходит ли за границы 7 эта цифра (иначе, нажата другая кнопка).
Потом проверяем, доступно ли оружие и не хотим ли мы выбрать то же оружие, что держим в руках.

Если все это проходит проверку, то убираем селектор с экрана, переносим данные нового оружия из одного места в памяти в другое и рисуем селектор в новом месте.

И вроде выглядит все равно криво (и я уверен, что это можно оптимизировать), но памяти это сэкономило немало.

🔥2

129 viewsAlex Logachev, 17:22