//@version=5
indicator("Kimchi Premium & USDKRW FX Trend", overlay=false, precision=2)

upbit = request.security("UPBIT:BTCKRW", timeframe.period, close)
bithumb = request.security("BITHUMB:BTCKRW", timeframe.period, close)
kr_avg_price = (upbit + bithumb) / 2

binance = request.security("BINANCE:BTCUSDT", timeframe.period, close)
okx = request.security("OKX:BTCUSDT", timeframe.period, close)
global_avg_price = (binance + okx) / 2

usdkrw = request.security("FX_IDC:USDKRW", timeframe.period, close)

fast_length = 12
slow_length = 26
signal_length = 9
[macd_line, signal_line, hist] = ta.macd(usdkrw, fast_length, slow_length, signal_length)

scale_factor = 5
macd_percent = (macd_line/usdkrw)*100 * scale_factor
signal_percent = (signal_line/usdkrw)*100 * scale_factor

kimchi_premium = ((kr_avg_price/(global_avg_price*usdkrw))-1)*100
upbit_premium = ((upbit/(global_avg_price*usdkrw))-1)*100
bithumb_premium = ((bithumb/(global_avg_price*usdkrw))-1)*100

show_details = input.bool(false, "Show Exchange Details")
sma_length = input.int(20, "MA Length", minval=1)
sma_kimchi = ta.sma(kimchi_premium, sma_length)

get_premium_color = kimchi_premium < -1 ? color.rgb(255, 59, 59) : kimchi_premium < 0 ? color.rgb(255, 165, 0) : kimchi_premium <= 1.5 ? color.rgb(76, 175, 80) : color.rgb(25, 118, 210)

plot(kimchi_premium, title="Kimchi Premium", color=get_premium_color, linewidth=2, style=plot.style_line)
plot(sma_kimchi, title="MA", color=color.new(color.blue, 50), linewidth=1)

macd_color = macd_line > signal_line ? color.new(color.red, 70) : color.new(color.blue, 70)
plot(macd_percent, title="MACD", color=macd_color, linewidth=1, style=plot.style_line)
plot(signal_percent, title="Signal", color=macd_color, linewidth=1, style=plot.style_line)

hline(2.5, color=color.new(color.blue, 50), linestyle=hline.style_dashed, title="2.5% Level")
hline(0.0, color=color.new(color.gray, 50), linestyle=hline.style_dashed, title="0% Level")
hline(-1.0, color=color.new(color.red, 50), linestyle=hline.style_dashed, title="-1% Level")

plot(show_details ? upbit_premium : na, title="Upbit Premium", color=color.new(color.yellow, 50))
plot(show_details ? bithumb_premium : na, title="Bithumb Premium", color=color.new(color.orange, 50))

if barstate.islast
    label.new(bar_index + 5, ta.highest(kimchi_premium, 500), "Average : " + str.tostring(kimchi_premium, "#.##") + "%\nUpbit: " + str.tostring(upbit_premium, "#.##") + "%\nBithumb: " + str.tostring(bithumb_premium, "#.##") + "%", color=color.black, style=label.style_label_left, textcolor=color.white)

is_golden_cross = macd_line > signal_line
crossunder_zero = ta.crossunder(kimchi_premium, 0)
buy_signal = crossunder_zero and is_golden_cross

bgcolor(buy_signal ? color.new(color.black, 90) : na)