CREATE OR REPLACE PROCEDURE p_get_anydata_value
 (
  p_param IN anydata
 ) IS
  l_anytype       anytype;
  l_typecode      PLS_INTEGER;
  l_varchar_value VARCHAR2(255 Char);
  l_num_value     NUMBER;
  l_collection    t_numbers;
  l_status        VARCHAR2(64 CHAR);
BEGIN
  -- Проверяем тип данных в ANYDATA
  l_typecode := p_param.GetType(l_anytype);

  IF l_typecode IN (dbms_types.TYPECODE_NAMEDCOLLECTION
                   ,dbms_types.TYPECODE_TABLE) THEN
    -- Извлекаем коллекцию
    IF p_param.GetCollection(l_collection) = dbms_types.SUCCESS THEN
      l_status := 'record_count=' || l_collection.count();
    ELSE
      l_status := 'ошибка извлечения коллекции';
    END IF;
  ELSIF l_typecode = dbms_types.TYPECODE_VARCHAR2 THEN
    IF p_param.GetVarchar2(l_varchar_value) = dbms_types.SUCCESS THEN
      l_status := l_varchar_value;
    END IF;
  ELSIF l_typecode = dbms_types.TYPECODE_NUMBER THEN
    IF p_param.GetNumber(l_num_value) = dbms_types.SUCCESS THEN
      l_status := l_num_value;
    END IF;
  ELSE
    l_status := 'неподдерживамый тип параметра';
  END IF;
  dbms_output.put_line(l_status);
END p_get_anydata_value;
/

create or replace type t_numbers is table of number;
/

begin
  dbms_output.put_line('anydata.ConvertNumber:');
  p_get_anydata_value(anydata.ConvertNumber(25));
  dbms_output.put_line('anydata.ConvertVarchar2:');
  p_get_anydata_value(anydata.ConvertVarchar2('Это строка'));
  dbms_output.put_line('anydata.ConvertCollection:');
  p_get_anydata_value(anydata.ConvertCollection(t_numbers(1, 2, 3, 4, 5)));
end;
/

anydata.ConvertNumber:
25
anydata.ConvertVarchar2:
Это строка
anydata.ConvertCollection:
record_count=5

DECLARE
  v_import_data t_credit_table;
  v_arguments   sys.jobarg_array;

BEGIN
  IF v_import_data IS NOT empty THEN
    v_arguments := sys.jobarg_array(
                      sys.jobarg(1, anydata.ConvertCollection(v_import_data)),
                      sys.jobarg(2, anydata.ConvertChar(const_pkg.c_yes)));

    -- Создадим и запустим джоб
    user_jobs_pkg.create_user_job(p_program_name   => 'p_process_contracts',
                                  p_program_action => $$PLSQL_UNIT || '.run_job',
                                  p_arguments      => v_arguments);
  END IF;
END;
/