#include <metal_stdlib>
using namespace metal;

float smin(float a, float b, float k) {
    if (k <= 0.0) return min(a, b);
    float h = clamp(0.5 + 0.5 * (b - a) / k, 0.0, 1.0);
    return mix(b, a, h) - k * h * (1.0 - h);
}

float sdRoundRect(float2 p, float2 b, float r) {
    float2 d = abs(p) - b + float2(r);
    return min(max(d.x, d.y), 0.0) + length(max(d, 0.0)) - r;
}

float sdCircle(float2 p, float r) {
    return length(p) - r;
}

[[ stitchable ]] half4 gooeyShader(float2 pos, 
                                   half4 currentColor, 
                                   float2 islandCenter, 
                                   float2 islandHalfSize, 
                                   float islandRadius, 
                                   float2 ballCenter, 
                                   float ballRadius, 
                                   float gooeyness) {
    
    float dIsland = sdRoundRect(pos - islandCenter, islandHalfSize, islandRadius);
    float dBall = sdCircle(pos - ballCenter, ballRadius);

    float clipPlane = islandCenter.y - pos.y + 6.0;
    float dBallClipped = max(dBall, clipPlane);

    float dMerged = smin(dIsland, dBallClipped, gooeyness);
    
    float alphaMerged = 1.0 - smoothstep(-0.5, 0.5, dMerged);
    
    float2 cutoutHalfSize = islandHalfSize + float2(6.0, 0.0);
    
    float dIslandCutout = sdRoundRect(pos - islandCenter, cutoutHalfSize, islandRadius);
    float alphaIslandCutout = 1.0 - smoothstep(-0.5, 0.5, dIslandCutout);
    
    float finalAlpha = clamp(alphaMerged - alphaIslandCutout, 0.0, 1.0);
    
    return half4(0.0, 0.0, 0.0, finalAlpha);
}