Вопрос - Я хочу выставить лимитный ордер, но мне необходимо чтобы при достижении заданной цены ордер исполнился сразу весь, даже если для этого придется покупать по невыгодной цене (аналог проскальзывания). Как это реализовать? Если я правильно понял, то при FOK, при нехватке ликвидности, ордер будет просто отменен и его придется выставлять заново.

Лимитка так не работает. То что вы хотите реализуется через алгоордера. На разных биржаж они называются и реализованы по разному. У бинанса это называется Stop Market Order. Вы указываете триггерную цену и при её достижении формируется маркетный ордер в любою сторону. Такое же есть у ByBit и называется у них Conditional Order и там можно выбрать срабатывание как Маркет Ордер .

// This Pine Script™ code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// Пример генерации Трейлинг Стопа
// ! Без цены активации
// ! В обе стороны
// © Azzrael

//@version=5
strategy(
 "EMA w Trailing [Azzrael]", 
 overlay=true, 
 pyramiding=0, 
 default_qty_type = strategy.percent_of_equity, 
 default_qty_value=100,
 initial_capital=100
 )


trail_dist = input.float(5, "Trail Distance %", minval=1, step=0.5) / 100
fast_ema_period = input.int(20, "Fast MA Period", minval=5, step=5)
slow_ema_period = input.int(100, "Slow MA Period", minval=10, step=10)

fast_ema = ta.ema(close, fast_ema_period)
slow_ema = ta.ema(close, slow_ema_period)
plot(fast_ema, color = color.yellow)
plot(slow_ema, color = color.green)

entry_long = ta.crossover(fast_ema, slow_ema)
entry_short = ta.crossunder(fast_ema, slow_ema)
var stop_price = 0.0

if strategy.position_size == 0
    stop_price := na
    if entry_long
        strategy.entry("long", strategy.long)
    else if entry_short
        strategy.entry("short", strategy.short)
else if strategy.position_size > 0
    stop_new = high * (1 - trail_dist)
    // stop_new = close * (1 - trail_dist)
    stop_price := na(stop_price) ? stop_new : math.max(stop_new, stop_price)
else if strategy.position_size < 0
    stop_new = low * (1 + trail_dist)
    // stop_new = close * (1 - trail_dist)
    stop_price := na(stop_price) ? stop_new : math.min(stop_new, stop_price)

if not na(stop_price) and stop_price != 0.0
    strategy.exit("exit", stop=stop_price)

plot(stop_price != 0.0 ? stop_price : na, color = color.red, style = plot.style_steplinebr)